Browse Category: Arduino

Stoppuhr

Ziel ist es eine Stoppuhr zu programmieren. die Funktionsweise ist sehr gut im Beitrag auf der Internetseite von Start Hardware (https://starthardware.org/stoppuhr-mit-arduino-und-segmentanzeige-arduino-tm1637/) beschrieben:

Die Stoppuhr besitzt eine Anzeige und zwei Taster. Zuerst zeigt die Stoppuhr einfach vier Nullen an. Wird nun der Start-Taster betätigt, fängt die Anzeige an, Sekunden hochzuzählen. Drückt man den Zwischenzeit-Taster, stoppt die Zeit auf dem Display. Im Hintergrund wird aber weitergezählt. Ein erneuter Druck auf den Zwischenzeit-Taster zeigt wieder die aktuell laufende Zeit an. Drückt man den Start-Taster, stoppt die Uhr sowohl im Display, als auch im Hintergrund. Nun kann man die Uhr entweder per Druck auf den Zwischenzeit-Taster weiter laufen lassen, oder durch erneuten Druck auf den Start-Taster auf Null zurücksetzen.
(© www.starthardware.org)

Um eine derartige Funktionalität zu erzeugen verwendet man vorzugsweise eine State Maschine oder auch Zustandsautomat genannt.

State Maschine (Zustandsautomat)

Ein endlicher Automat (EA, auch Zustandsmaschine, Zustandsautomat; englisch finite state machine, FSM) ist ein Modell eines Verhaltens, bestehend aus Zuständen, Zustandsübergängen und Aktionen. Ein Automat heißt endlich, wenn die Menge der Zustände, die er annehmen kann (später S genannt), endlich ist. Ein endlicher Automat ist ein Spezialfall aus der Menge der Automaten.

Ein Zustandsautomat ist ein mathematisches Modell zur Verhaltensbeschreibung formaler Systeme . Es ist eine sogenannte abstrakte Maschine , die sich zu jeder Zeit in genau einem von endlich vielen Zuständen befinden kann. Der ZA kann als Reaktion auf Eingaben (Events) von einem Zustand in einen anderen wechseln ; der Wechsel von einem Zustand in einen anderen wird als Zustands-Übergang bezeichnet .

Damit lassen sich beliebig komplexe Steuerungsabläufe beschreiben und Relativ einfach in gängigen Programmiersprachen implementieren. Dazu bedient man sich einer sogenannten Zustandstabelle. In dieser ist für jeden Zustand beschrieben bei welchen Ereignissen welcher Folgezustand eingenommen wird.

Ziel ist es dabei immer, die eigentliche Maschine, also das was in der Zustandstabelle ausgedrückt wird, so einfach und überschaubar wie möglich zu präsentieren. Sie implementiert die Logik und definiert was die Maschine (in unserem Fall natürlich das Programm) eigentlich macht und warum sie es macht. Für unsere Stoppuhr ist folgende Zustandsmaschine aus der Spezifikation entstanden:

switch (programState) {
  case 0: // gestoppt
    // hier werden einfach vier Nullen auf dem Display angezeigt
    // wird der Start-Taster gerdückt, springe zu State 1
    break;

case 1: // gestartet
    // zeige die vergangene Zeit auf dem Display
    // Wenn der Zwischenzeit-Taster gedrückt wird, springe zu State 2
    // Wenn der Start-Taster gedrückt wird, springe zu State 3
    break;
case 2: // Zwischenzeit anzeigen
    // zeige die Zwischenzeit an
    // Wenn der Zwischenzeit-Taster gedrückt wird, springe zu State 1
    break;
case 3: // gestoppt
    // Wenn der Zwischenzeit-Taster gedrückt wird, springe zu State 1 (weiter laufen)
    // Wenn der Start-Taster gedrückt wird, springe zu State 0 (löschen)
    break;
  }

Die Umsetzung erfolgt in meinem Fall nicht mit einer 7-Segmentanzeige sondern mit Hilfe eines 2-zeiligen LCD Displays. Das entsprechende Programm sieht dann so aus:

//=====================================
// Stoppuhr
// PHOF 2021
// Uno mit LCD inspiriert vom Beitrag 
// auf www.starthardware.org
//=====================================

#define numberOfSeconds(_time_) ((_time_ / 1000) % 60)
#define numberOfMinutes(_time_) (((_time_ / 1000) / 60) % 60)

#include <Wire.h> 

#include <LiquidCrystal_I2C.h>
LiquidCrystal_I2C lcd(0x27,20,2);

int startPin = 8; // start, stop, delete
int zwischenzeitPin = 9; // pause, continue
int stateStart;
int stateZwischenzeit;
int lastStateStart;
int lastStateZwischenzeit;

int programState = 0;

unsigned long startZeit = 0;
long zwischenzeit = 0;
long zeitAngehalten = 0;

char LCD_Line1[40];

void setup(){
  Serial.begin(9600);
  lcd.init(); lcd.backlight();
  lcd.setCursor(0,0);  lcd.print("Stoppuhr");
  sprintf(LCD_Line1, "%02d:%02d", 0, 0); // Start-Anzeige
  lcd.setCursor(6,1);lcd.print(LCD_Line1);
  pinMode(zwischenzeitPin, INPUT);
  pinMode(startPin, INPUT);
 
}// end loop


void showTime(long theTime) {
  unsigned long myTime = theTime - startZeit;
  int seconds = numberOfSeconds(myTime);
  int minutes = numberOfMinutes(myTime);
  
  sprintf(LCD_Line1, "%02d:%02d", minutes, seconds);
  lcd.setCursor(6,1);lcd.print(LCD_Line1);
  Serial.print(minutes);Serial.print(" min : ");
  Serial.print(seconds); Serial.println(" sec");

}// end showTime


void loop(){
  stateStart = digitalRead(startPin);
  stateZwischenzeit = digitalRead(zwischenzeitPin);
  
  switch (programState) {
    case 0: // gestoppt
      startZeit = 0; 
      // start
      if ((stateStart == LOW) && (stateStart != lastStateStart)) {
        startZeit = millis();
        programState = 1;
      }
      break;
    case 1: // gestartet
      showTime(millis());
      // zwischenzeit
      if ((stateZwischenzeit == LOW) && (stateZwischenzeit != lastStateZwischenzeit)) {
        zwischenzeit = millis();
        programState = 2;
      }
      // stop
      if ((stateStart == LOW) && (stateStart != lastStateStart)) {
        zeitAngehalten = millis();
        programState = 3;
      }
      break;
    case 2: // zwischenzeit
      showTime(zwischenzeit);
      // zwischenzeit ausblenden
      if ((stateZwischenzeit == LOW) && (stateZwischenzeit != lastStateZwischenzeit)) {
        programState = 1;
      }
      break;
    case 3: // gestoppt
      // weiter laufen lassen
      if ((stateZwischenzeit == LOW) && (stateZwischenzeit != lastStateZwischenzeit)) {
        startZeit = startZeit + (millis() - zeitAngehalten);
        programState = 1;
      }
      // löschen
      if ((stateStart == LOW) && (stateStart != lastStateStart)) {
        programState = 0;
      }
      break;
  } // end case

  lastStateStart = stateStart;
  lastStateZwischenzeit = stateZwischenzeit;

}

Brushless Motor Ansteuerung

Ein BLDC-Motor besteht aus zwei Hauptteilen, einem Stator und einem Rotor. In dieser Darstellung ist der Rotor ein Permanentmagnet mit zwei Polen, während der Stator aus Spulen besteht, die wie im Bild unten gezeigt angeordnet sind.

Prinzip-Schaubild eines BLDC Motors (Graphiken inspiriert von howtomechatronics.com)

Funktionsweise

Die Funktionsweise ist analog zu einem klassischen Motor. Sobald Strom durch die Spule fliesst, entsteht ein Magnetfeld, dessen Pole von der Richtung des Stroms abhängt. So dass je nach der Stromrichtung an der Spule ein anziehendes oder abstossendes Magnetfeld erzeugt werden kann.

Wird nun jede Spule nacheinander so angesteuert, dass die entstehende Kraftwirkung zwischen Stator und Rotor eine Drehwirkung erzeugt haben wir einen Motor.

Um die Effizienz des Motors zu erhöhen, können wir zwei gegenüberliegende Spulen als einzelne Spule so wickeln, dass entgegengesetzte Pole zu den Rotorpolen erzeugt werden, wodurch wir eine doppelte Anziehungskraft erhalten.

Optimierungsschritte (© howtomechatronics.com)

Mit dieser Konfiguration können wir die sechs Pole am Stator mit nur drei Spulen oder Phase erzeugen. Wir können den Wirkungsgrad weiter steigern, indem wir zwei Spulen gleichzeitig bestromen. Auf diese Weise wird eine Spule den Rotor anziehen und die andere Spule abstoßen. Damit ist leicht abzulesen, dass für eine 360 Grad Drehung des Rotors sechs Schritte erforderlich sind:

Wenn wir uns die Stromwellenform ansehen, können wir feststellen, dass in jedem Intervall eine Phase mit positivem Strom, eine Phase mit negativem Strom und die dritte Phase ausgeschaltet ist. Dies ergibt die Idee, dass wir die freien Endpunkte jeder der drei Phasen miteinander verbinden und so den Strom zwischen ihnen aufteilen oder einen einzelnen Strom verwenden können, um die beiden Phasen gleichzeitig zu erregen.

Hier ist ein Beispiel. Wenn wir im obigen Beispiel Phase A mit einer Art Schalter, zum Beispiel einem MOSFET, an die positive Gleichspannung anschließen und auf der anderen Seite die Phase B mit Masse verbinden, dann fließt der Strom von VCC durch Phase A, den Sternpunkt und Phase B, an Masse. So erzeugten wir mit nur einem einzigen Stromfluss die vier verschiedenen Pole, die den Rotor in Bewegung setzen.


Bei dieser Konfiguration haben wir tatsächlich eine Sternschaltung der Motorphasen, bei der der Sternpunkt intern verbunden ist und die anderen drei Enden der Phasen aus dem Motor herauskommen, und deshalb kommen beim bürstenlosen Motor drei Drähte heraus.

Prinzipschaltbild (inspiriert von © howtomechatronics.com)


Damit der Rotor den vollen Zyklus macht, müssen wir nur die richtigen zwei MOSFETS in jedem der 6 Intervalle aktivieren und genau darum geht es bei ESCs. Ein ESC (=elektronischer Geschwindigkeitsregler) steuert die Bewegung oder Geschwindigkeit des bürstenlosen Motors, indem er die entsprechenden MOSFETs aktiviert, um das rotierende Magnetfeld zu erzeugen, damit sich der Motor dreht. Je höher die Frequenz oder je schneller der ESC die 6 Intervalle durchläuft, desto höher ist die Drehzahl des Motors.

Ansteuerung mit einem Steuergerät

Es gibt verschiedene elektronische Steuergeräte im Internet. Hier soll an einem Beispiel gezeigt werden, wie damit ein ausgedienter Elektro-Rasenmäher-Motor angesteuert werden kann.

Das mir vorliegende Gerät mit der Bezeichnung WS55-220 kommt von einem chinesischen Hersteller ohne weitere Erklärungen. Es hat mehrere Anschlüsse die wie folgt gekennzeichnet sind:

Anschlussbild 1

Daneben finden sich weitere Bilder im Internet, aus denen eine mögliche Beschattung hervorgeht:

Anschlussbild 2

Meine eigenen Untersuchungen haben nach einigem Suchen dann auch zu der Erkenntnis geführt, dass die Steuersignale sich alle auf Masse beziehen und dann zu folgendem Schaltbild geführt.

Ansteuerung über einen Arduino

Möchte man die Ansteuerung anstelle des meist mit gelieferten Potentiometer mit einem Microcontroller durchführen, so muss die Spannungsteilung des Potentiometers durch einen MOSFET Transistor übernommen werden, der über ein PWM Signal angesteuert wird.

Aus dem obigen Prinzipschaltbild geht hervor, dass vom Controller eine Steuerspannung von +10V die über das Potentiometer an den Eingang SV geführt wird. Aus diesem Grund liegt der Ansatz nahe, eine typische MOSFET Motor-Ansteuerung herzunehmen und anstelle des Motors die Anschlüsse SV und +10V zu verwenden.

Schaltbild zum Ansteuern des Motorcontrollers über ein PWM Signal

Das zugehörige Test-Programm sieht so aus:

/*
 * Test-Programm für den Arduino UNO
 * PHOF Okt 2021
 * PWM Signal 255 = Motor Aus / 0 = Motor full speed 
 * 
 */


int analogPin = 9;   // PWM output to Input Gate of Mosfet
int i;        

void setup(){ 
  Serial.begin(115200);
}

void loop(){
  for (i=255; i>0;i=i-5){
    Serial.print("Value is:");
    Serial.println(i);
    analogWrite(analogPin, i);  // PWM out from 255 to 0 for Speed Control
    delay(3000);
  } //end for
}//end loop

Port-Erweiterung durch Schieberegister

Ein Schieberegister ist eine logische Schaltung, die mehrstellige binäre Signale taktgesteuert aufnehmen, speichern und wieder abgeben kann. Schieberegister ermöglichen die Transformation serieller Daten in parallele Daten und umgekehrt. Sie bestehen im Grunde aus hintereinander geschalteten D- oder JK-FlipFlops. Die Takteingänge aller Stufen werden zusammengeschaltet und über einen gemeinsamen Takt versorgt.

Da ein Flip-Flop nur ein Bit speichern kann, müssen je nach Anwendung mehrere Flip-Flops zu einem Schieberegister zusammengeschaltet werden. Bei dem weit verbreiteten IC vom Typ 74HC595 beispielsweise sind 8 FlipFlops integriert, so kann man mit lediglich 3 Arduino-Pins 8 Ausgangspins ansteuern.

Der Schaltkreis hat folgende Pin-Belegung:

Funktionsweise

Die Funktionsweise eines Schieberegisters kann man sichwie in obiger Abbildung vorstellen: Ein serieller Datenstrom wird über eine Datenleitung an den Daten-Pin DS des Bausteins übertragen. Solange das ShiftClock-Pin (SHCP) auf Low steht passiert vorerst gar nichts. Erst wenn ein Pegelwechsel von LOW nach HIGH am ShiftClock-Pin erfolgt, wird der Zustand der am DS-Pin anliegt in den Zwischenspeicher geschoben.

Funktions-Schema eines Schieberegisters

Dieser Vorgang kann beliebig oft wiederholt werden, bis der Zwischenspeicher voll ist oder genügend Daten aufgenommen wurden. Da ein Schieberegister genau genommen aus zwei Registern besteht: dem Schieberegister, in welches der Zustand der einzelnen Ausgangspins seriell, also Bit für Bit gesteuert über das ShiftClock-Pin (SHCP) geschoben wird. Und das Ausgangsregister, in das der Zustand des Schieberegisters über ein weiteres Signal am sogenannten Storage Register Clock-Pin (SRCP) hin kopiert wird.

Es handelt sich somit um zwei separierte Register deren Datenströme kontrolliert Über die Pegelwechsel von LOW nach HIGH an den beiden Steuer-Pins ShiftClock-Pin (SHCP) und Storage Register Clock-Pin (SRCP) zusammen gefügt werden können.

Beispiel Programm

//------------------------------
// Schiebregister Test
//------------------------------

int shiftPin = 4; //SH_CP_PIN
int storePin = 2; //ST_CP_PIN
int dataPin = 7;  //DS_PIN
// Dieses Muster soll ausgegeben werden
int muster[8] = {1,1,1,1,1,1,0,0}; 
 
void setup() {
 pinMode(storePin, OUTPUT);
 pinMode(shiftPin, OUTPUT);
 pinMode(dataPin, OUTPUT);
 
 digitalWrite(storePin, LOW); // storePin sicherheitshalber auf LOW

 for (int i=0; i<8; i++) {
     digitalWrite(shiftPin, LOW);
     digitalWrite(dataPin, muster[i]);
     digitalWrite(shiftPin, HIGH);
    } // end for
 
// wenn alle Daten übertragen, auf Ausgabe schalten   
 digitalWrite(storePin, HIGH);
}
 
void loop () {
}

 

Mehrere Schieberegister zusammenschalten

Als Beispiel für die Möglichkeiten mehr als 8 Ausgänge zu steuern, habe ich eine Schaltung mit 3 IC 74595 entwickelt. Aufgebaut als Experimentierplattform für den Arduino und entsprechenden Anschlussmöglichkeiten auf einer Lochrasterplatine prototypisch umgesetzt.

Prototyp einer 24Bit-Port-Erweiterung mit 3 IC 74595 Bausteinen

Die Ansteuerung erfolgt wie bei einem einzelnen Schaltkreis d.h. alle Steuersignale an den Pins SHCP und SRCP werden parallel an alle ICs angeschlossen. Nur die DS-Leitungen der zweiten und folgenden Schieberegister werden kaskadiert. Dh. der Überlauf-Ausgang Q7S des ersten Schieberegisters wird mit dem DS-Eingang des 2. Registers verbunden usw. Das folgende Blockschaltbild verdeutlicht das Prinzip.

Drehstellgeber

In Bearbeitung…

Das Funktionsprinzip: Im Innern eines Encoders (Impulsgebers) sind zwei Taster integriert. Sie schalten um einen halben Klick Phasenverschoben. Detektiert man auf dem Kanal 1 (also vom ersten Taster) einen Wechsel von LOW zu HIGH prüft man, ob Kanal 2 LOW ist. Ist dieser LOW, wurde in die eine Richtung gedreht, ist er HIGH, wurde er in die andere Richtung gedreht.

Das Ganze funktioniert natürlich auch in die andere Richtung: Detektiert man auf dem Kanal 1 (also vom ersten Taster) einen Wechsel von HIGH zu LOW prüft man, ob Kanal 2 HIGH ist. Ist dieser HIGH, wurde in die eine Richtung gedreht, ist er LOW, wurde er in die andere Richtung gedreht.

Dazu muss man zu Beginn festlegen wie man die beiden möglichen Drehrichtungen benennen möchte, da sonst Verwirrungen entstehen können.

int encoderPinA = 2;
int encoderPinB = 3;
int encoderPos = 0;
int encoderPinALast = LOW;
int encoderPinANow = LOW;

void setup() {
  pinMode (encoderPinA, INPUT_PULLUP);
  pinMode (encoderPinB, INPUT_PULLUP);
  Serial.begin (115200);
}

void loop() {
  encoderPinANow = digitalRead(encoderPinA);
  if ((encoderPinALast == HIGH) && (encoderPinANow == LOW)) {
    if (digitalRead(encoderPinB) == HIGH) {
      encoderPos++;
    } else {
      encoderPos--;
    }
    Serial.println(encoderPos);
  }
  encoderPinALast = encoderPinANow;
}

Temperatursensoren

DS18B20

Beim DS18B20 handelt es sich um einen digitalen Temperatursensor im TO92 Gehäuse, der über einen One-Wire-Bus angesprochen wird. Auf diese Weise ist es möglich mehrere Sensoren an einem Mikrocontroller-Pin anzuschließen. Der Sensor besitzt eine Auflösung von 12 Bit und eine Messgenauigkeit von ±0.5°C im Messbereich von -55°C bis +125°C.

PIN Belegung (Quelle: AZ-Delivery.com)

Für die Funktion wird der Widerstand R1 = 4,7kOhm (Pullup-Widerstand genannt) zwischen Vcc und dem Daten Pin benötigt, weil er die Spannung bei fehlendem Signal auf die Versorgungsspannung hochzieht), was im Datenblatt so nicht gleich ersichtlich ist.

Der serielle Datenbus (1-Wire-Bus) und das vom Sensor verwendete Protokoll erfordern erheblichen Programmieraufwand, daher wird in den meisten Fällen auf vordefinierte Funktionsbibliotheken zurück gegriffen.

DHT 11 und DHT 22

Der DHT22 ist ein zuverlässiger Sensor zum ermitteln von Temperatur und Luftfeuchtigkeit. Da der Sensor sowohl mit 3,3V als auch 5V betrieben werden kann, eignet er sich zum Anschluss an alle gängige Boards

DHT 22 Sensor PIN Belegung (Quelle: Adafruit.com)

ESPLORA Board

Der Arduino Esplora ist ein Board aus den Anfängern der Arduino Ära, das heute nicht mehr gebaut wird. Die Besonderheit dieses Boards, ist die Ausstattung mit unterschiedlichen Bausteinen. Für Eingaben gibt es einen Joystick, vier Tasten, einen Lichtsensor, einen Schieberegler, ein Mikrofon, einen Temperatursensor und einen Beschleunigungsmesser. Für die Ausgänge gibt es einen Summer und eine dreifarbige LED. Auf den ersten Blick sieht es aus wie ein Videospiel-Controller.

ESPLORA Board (Quelle: Arduino.cc)

Infolgedessen unterscheidet sich die Programmierung etwas von der für andere Arduino-Boards. Es verfügt über eine eigene Bibliothek, die das Lesen von den Eingangssensoren und das Schreiben auf die Ausgangsaktoren erleichtert. Informationen zur Verwendung der Bibliothek finden Sie in diesem Handbuch und auf den Referenzseiten der Esplora-Bibliothek.

Der Arduino Esplora verfügt über eine Reihe von Funktionen für die einfache Verbindung mit den auf der Platine montierten Sensoren und Aktoren. Auf die Funktionen kann über die Esplora-Klasse zugegriffen werden. Die Bibliothek bietet einfachen Zugriff auf die Daten von den integrierten Sensoren und bietet die Möglichkeit, den Status der Ausgänge zu ändern.

Esplora Temperatur Sensor

Das folgende Programm zeigt, wie man den Temperatursensor des Esplora verwenden kann. Die Funktion Esplora.readTemperature () ruft den Wert vom Temperatursensor ab. Je nach Ihrer Wahl erhalten Sie die Temperatur in Grad Celsius oder Grad Fahrenheit. Es wird ein Parameter benötigt, DEGREES_C für Celsius oder DEGREES_F für Fahrenheit.

#include <Esplora.h>

void setup() {
  Serial.begin(9600);      // initialize serial communications with your computer
}

void loop() {
  // read the temperature sensor in Celsius, then Fahrenheit:
  int celsius = Esplora.readTemperature(DEGREES_C);
  int fahrenheit = Esplora.readTemperature(DEGREES_F);

  // print the results:
  Serial.print("Temperature is: ");
  Serial.print(celsius);
  Serial.print(" degrees Celsius, or ");
  Serial.print(fahrenheit);
  Serial.println(" degrees Fahrenheit.");
  Serial.println("     Fahrenheit = (9/5 * Celsius) + 32");

  delay(1000);
}

Esplora Digital Write

Um Daten Auszugeben, können die üblichen Funktionen verwendet werden. Auf dem oben abgebildeten „inoffiziellen“ Esplora Diagramm kann man entnehmen, dass ein Ausgang über den Digitalen Pin 3 am Thinkerboard Stecker möglich ist.

// include the Esplora library
#include <Esplora.h>

void setup() {

pinMode(3,OUTPUT);
digitalWrite(3,HIGH);
}

void loop() {
}

DC Motor-Steuerung

Elektromotoren können relativ einfach gesteuert werden. Motorsteuerung bedeutet im einfachsten Fall, den Motor in Bewegung zu versetzen. Dies geschieht in dem die Wicklungen des Motors mit Spannung versorgt werden. Dabei gibt es nur zwei Zustände: der Motor ist mit Spannung versorgt und dreht sich oder im anderen Fall eben nicht.

Um die Richtung des Motors zu wechseln, muss der Stromfluss in der Spule umgekehrt werden. Um dies ohne manuelles umpolen der Spannungsquelle zu erreichen, ist eine spezielle Schaltung erforderlich, die auf geschickte Art das automatische Umpolen ermöglicht. Die Schaltung hat ihren Namen von der Form wie die Schalter angeordnet sind. Da sie wie ein „H“ aus sieht wird sie als H-Schaltung oder H-Brücke bezeichnet. Eine solche H-Brücke sieht schematisch so aus:

Die rote Linie zeigt den Stromweg für die jeweilige Drehrichtung. Sind die Schalter 1 und 4 geschlossen, so dreht sich der Motor rechts herum. Schliesst man die Schalter 2 und 3 dreht sich der Motor in die andere Richtung. Wobei zu beachten ist, dass nicht alle theoretisch möglichen Schalterstellung zugelassen werden, um beispielsweise Kurzschlüsse zu vermeiden. Die Betriebsspannung U ist die Spannung für den Motor, die meist unabhängig von der Logik ist und auch höher gewählt werden kann als 12 V.

Steuerung der Motor-Geschwindigkeit

Die Geschwindigkeit eines Motors ist direkt proportional zur angelegten Spannung. Dies ermöglicht eine Geschwindigkeitsregulierung, indem eine Puls-Weiten-Modulation (PWM) verwendet wird.

Pulsweitenmodulation oder PWM ist eine Technik, die digitale Methoden verwendet, um analoge Ergebnisse zu erhalten. Bei der Pulsweitenmodulation nimmt man ein Rechtecksignal mit einer festen Frequenz und variiert die Breite der jeweiligen Pulse. Den Abstand zweier aufeinander folgender Pulse bezeichnet man als Periodendauer, die Breite des aktiven Pulses als Pulsweite. Das Verhältnis von Pulsweite zu Periodendauer bezeichnet man auch als „Duty Cycle“(also die Zeit, in der der Pin im Dienst ist).

Programmtechnisch kann ein PWM-Signal wie in der Graphik gezeigt erzeugt werden, und beispielsweise zur Geschwindigkeitsregelung an einem Gleichstrommotor verwendet werden. Dies ist möglich, weil die Geschwindigkeit eines Motors direkt proportional zur angelegten Spannung ist. Somit ermöglicht die Veränderung der Spannung über das erzeugte Verhältnis T1 zu T1+T2 die Geschwindigkeitsregulierung am Motor.

Standardmäßig bietet der Arduino mit dem Befehl AnalogWrite(…) die Möglichkeit, PWM-Signale mit einer Auflösung von 8 Bit und einer PWM-Frequenz von 490 Hz (Pin D3, D9, D10 und D11) bzw. 980 Hz (Pin D5 und D6) auszugeben. Die Funktion AnalogWrite sendet pseudo-analoge Werte mittels einer hardwarebasierten Pulsweiten Modulation (PWM) an den adressierten Ausgangspin. Diese arbeitet nach folgendem Prinzip: Ein Wert 0 generiert eine gleichmäßige Spannung von 0 Volt; Ein Wert von 255 generiert eine gleichmäßige Spannung von 5 Volt an einem festgelegten PIN. Für Werte zwischen 0 und 255 wechselt der PIN sehr schnell zwischen 0 und 5 Volt – je höher der Wert, desto länger ist der PIN auf HIGH (5 Volt).

In der nachfolgenden Tabelle werden einige markante Tastwerte den entsprechenden PWM Werten gegenüber gestellt. Würde man beispielsweise analogWrite(5, 64); eingeben, so würde am Pin 5 ein Signal mit einem Tastgrad von 25% ausgegeben werden.

Tastgrad0 %25%50%75%100%
PWM-Wert064128191255

Ansteuerung eines DC Motors

In der Praxis verwendet man keine einzelnen Transistoren sondern hochintegrierte Schaltkreise, die sämtliche Bauteile für eine Motorsteuerung enthalten. Ein Beispiel wäre der Baustein L293 D, der über 600mA Strom liefern kann. Daneben gibt es noch weit leistungsstärkere wie den L298 D der mit über 2A Motoren steuern kann. Im nachfolgenden Blockschaltbild ist der prinzipielle Aufbau schematisch dargestellt:

Blockschaltbild des IC L293 (Quelle www.ti.com)

Die Ansteuerung eines Motors ist damit relativ unkompliziert machbar. Wichtig ist dabei auf die unterschiedlichen Spannungsversorgungen zu achten. Der Baustein kann ohne Probleme mit 5V Spannung vom Arduino betrieben werden. Da die zu steuernden Motoren aber meist größere Spannungen benötigen, besteht die Möglichkeit eine externe Spannungsquelle an PIN 8 des Bausteins anzuschliessen. Der Masse Anschluss wird dagegen von beiden Spannungen verwendet.

Die Steuerung des Motors erfolgt über die beiden Eingänge IN1 und IN2 die mit den digitalen Ausgängen des Arduinos verbunden werden. Dabei können folgende vier Zustände auftreten:

Eingang IN 1Eingang IN 2Motor Verhalten
LOWLOWMotor Stoppt
LOWHIGHMotor dreht sich nach Links
HIGHLOWMotor dreht sich nach rechts
HIGHHIGHMotor stoppt

Eine elementare Steuerung mit dem Arduino sieht im einfachsten Fall so aus:

const int PIN_A = 7;
const int PIN_B = 8;

void setup () {
  Serial.begin(9600); 
  pinMode(PIN_A , OUTPUT);
  pinMode(PIN_B , OUTPUT); 
 
  // Motor nach rechts drehen
  digitalWrite(PIN_A, LOW); 
  digitalWrite(PIN_B, HIGH);

  // Motor nach links drehen
   digitalWrite(PIN_A, HIGH); 
   digitalWrite(PIN_B, LOW);
void loop() { }

Wii Nunchuk Controller als Steuerelement am Arduino

In Bearbeitung …

Der Nunchuck Controller ist ein Eingabe-Instrument für die bekannte Wii-Spieleconsole. Er verfügt über 2 Druckknöpfe, einen Joystick und einen eingebauten 3-Achsen-Beschleunigungssensor. Dieser Controller ist aufgrund der hohen Verbreitung für wenig Geld erhältlich, sehr robust und verfügt über eine gut dokumentierte I2C-Schnittstelle, die es erlaubt, diesen mit dem Arduino zu verbinden. Somit kann der Controller für die verschiedensten Steuerungsaufgaben zweckentfremdet werden.

Älterer Wii-Nunchuk-Controller

Da viele Maker diesen Controller bereits in Ihren Projekten verwenden, finden sich viele Programm-Bibliotheken im Internet, die eine einfache Verwendung erlauben. Die hier verwendete Bibliothek stellt folgende Funktionen bereit:

void nunchuk_setpowerpins()void nunchuk_init()
int nunchuk_get_data()void nunchuk_calibrate_joy()
inline unsigned int nunchuk_zbutton()inline unsigned int nunchuk_cbutton()
inline int nunchuk_joy_x()inline uint16_t nunchuk_accelx()
inline int nunchuk_cjoy_x()inline uint16_t nunchuk_accely()
inline int nunchuk_cjoy_y()inline uint16_t nunchuk_accelz()
inline int nunchuk_joyangle()void nunchuk_calibrate_accelxy()
inline int nunchuk_rollangle()void nunchuk_calibrate_accelz()
inline int nunchuk_pitchangle()
Funktionen der wiinunchuk-Bibliothek

Die Bibliothek bereitet die Daten vom Controller so auf, dass diese über eine Anweisung ausgelesen werden können. Insgesamt benötigt man einen Speicherpuffer mit 75 Zeichen, in die sämtliche Sensorwerte geschrieben werden. Wie das geht, zeigt das erste Beispiel-Programm, dass nur die Joystick-Position und die Zustände der beiden Schalter C und Z ausliest.

#include <Wire.h>
#include <wiinunchuck.h>

void setup() { 
  Serial.begin(9600);
  nunchuk_init(); // Nunchuk initialisieren, Joystick auf Mittelposition
  delay(100);
  nunchuk_calibrate_joy();
  delay(100);
}
 
void loop() {
  nunchuk_get_data();   // Daten (6 Byte) vom Nunchuk Controller auslesen 
  char buffer[25];
  sprintf(buffer, "X:%3d Y:%3d Z:%1d C:%1d", 
          nunchuk_cjoy_x(), nunchuk_cjoy_y(), 
          nunchuk_zbutton(), nunchuk_cbutton() );
  Serial.println(buffer);   // Zusammengesetzten String an seriellen Monitor schicken
  delay(50);
}

Der Nunchuk wird über ein einfaches I²C Protokoll angesprochen. Mit Hilfe eines Befehles können wir alle Daten aus dem Nunchuk lesen. Die Daten kommen dabei als Paket von 6 Bytes in folgendem Format:

Byte 1: Joystick – X
Byte 2: Joystick – Y
Byte 3: ACC X (9..2)
Byte 4: ACC Y (9..2)
Byte 5: ACC Z (9..2)
Byte 6: ist aufgeteilt in Bits
Bit 0: Z-Taste
Bit 1: C-Taste
Bit 2,3: fehlenden Bits 0,1 vom ACC X
Bit 4,5: fehlenden Bits 0,1 vom ACC Y
Bit 6,7: fehlenden Bits 0,1 vom ACC Z

Um die Daten mit einem Arduino verarbeiten zu können, muss der Controller natürlich mit dem Arduino verbunden werden. Es gibt sechs Steckplätze, wobei nur die vier Äusseren belegt sind.

Wii-Steckerbelegung, die Farben können allerdings variieren.

Es gibt Adapter, aber aufgrund der Tatsache, dass ich meine nicht mehr anderswo benötige, habe ich den Stecker einfach abgeschnitten und Arduino-kompatibel mit Steckbrücken versehen.

Steuerpult fürs Hobbylabor

Beitrag befindet sich in Bearbeitung ….

Mit dem Arduino lassen sich ja sehr einfach verschiedenste Steuerungsaufgaben erledigen. Die Möglichkeit über Steckbretter und Steckbrücken, die Aufbauten schnell umzusetzen sind schon sehr praktisch. Wenn man allerdings, verschiedene Steuerungen und Anzeigeeinheiten immer wieder benötigt, habe ich mir überlegt ein Arduino-Steuerpult zu bauen. Mit dem Ziel immer wieder benötigte Module stationär in ein Gehäuse mit Netzteil zu integrieren, so dass immer wieder darauf zugegriffen werden kann.

In meinem Steuerpult sind in der ersten Ausbaustufe folgende Module enthalten:

  • Netzteil mit 12V und 5V bei ca. 2A Ausgangsleistung
  • Digitales Voltmeter
  • LCD-Anzeige, 4 Zeilen und I2C Schnittstelle
  • 2×14-Segement-Anzeigen mit I2C Schnittstelle
  • Potentiometer
  • Dreh-Encoder
  • 3-Tasten, mit Pulldowns Widerständen
  • 12er Tastenfeld
  • Thermo-Drucker
  • Bepper um Töne zu erzeugen
  • Schalt-Transistoren (in Ausbaustufe 2)
  • Motor-Regler (in Ausbaustufe 2)

Dazu wurde eine Frontplatte entworfen Mund mit einer Holzfräse von Inventables realisiert:

Frontplatten-Entwurf mit Easel

Nach dem die Frontplatte entworfen und ausgefräst war, habe ich dazu passend ein Gehäuse geplant… und mit Hilfe von MDF Platten in meiner Holzwerkstatt zusammengebaut.

Die Idee ist nun, die Anschlüsse Module an der Vorderseite über Klemmleisten heraus zu führen, um diese von einem Arduino ansteuern zu können. Die immer wieder verwendeten Leitungen wie die Strom-Versorgung werden intern fest mit dem Netzgerät verdrahtet, so dass der Arduino davon unbelastet bleibt. Einzig die gemeinsame Masseleitung wird benötigt. Das verringert den Verkabelungsaufwand bei neuen Projekten erheblich.

Am Ende sieht das Ganze dan beispielsweise so aus:

Natürlich können noch wesentlich mehr Funktionsmodule eingebaut werden. Der Phantasie sind hier keine Grenzen gesetzt.

Thermodrucker mit dem Arduino ansteuern

Es gibt verschiedene Anwendungen wo es Sinn macht, dass Daten ausgedruckt werden können. Dazu ist kein großer Drucker erforderlich, kompakte Thermodrucker ähnlich einem Kassenbon-Drucker eignen sich ganz hervorragend dafür.

Im Internet (z.B. bei Adafruit) kann man an verschiedenen Stellen einen günstigen Thermo-Drucker bestellen. Dieser Drucker entspricht einfachen Kassenbon-Drucker. Der Thermodrucker nimmt ein 2,55″ (57 mm) breites Thermopapier mit einem maximalen Rollendurchmesser von 1,5″ (39 mm) auf. Möglicherweise muss etwas Papier von diesen Rollen entfernen, damit es in den Drucker passt. Aber man kann immer das überschüssige Papier im Drucker verwenden, da kein „Kern“ im Papier vorhanden sein muss, damit es eingezogen werden kann.

Die Rückseite meines Druckers hat zwei Anschlüsse; einen für die Stromversorgung und einen (5-poligen) für die serielle Kommunikation (Varianten die davon abweichen sind möglich). Der Thermodrucker wird mit einer Standard-Baudrate von 19200 Bit ausgeliefert. Wenn der Drucker in Verbindung mit einem Arduino verwendet werden soll, muß ein externes Netzteil (5V/2A) angeschlossen werden, da der Drucker mehr Strom aufnimmt, als USB liefern kann.

Rückseite mit Anschlussbildern des Thermodruckers

Ich habe den Drucker in ein einfaches Holzgehäuse eingebaut um erste Test durchführen zu können. Zum Test habe ich 3 der 5 Leitungen verwendet und zwar die blaue mit dem RX-Pin und die grüne mit dem TX-Pin am Arduino (näheres siehe im Quellcode). Ebenso wurde die schwarze Leitung mit GND am Arduino verbunden und natürlich die externe Stromversorgung des Druckers mit 5-9V. Wichtig ist noch auf die Baudrate zu achten. Hier gibt es 2 Versionen. Die 19200 und die 9600 Rate… je nach dem mit welcher der Drucker vorkonfiguriert wurde.

Ich habe den Drucker in ein einfaches Holzgehäuse eingebaut um erste Test durchführen zu können. Zum Test habe ich 3 der 5 Leitungen verwendet und zwar die blaue mit dem RX-Pin und die grüne mit dem TX-Pin am Arduino (näheres siehe im Quellcode). Ebenso wurde die schwarze Leitung mit GND am Arduino verbunden und natürlich die externe Stromversorgung des Druckers mit 5-9V. Wichtig ist noch auf die Baudrate zu achten. Hier gibt es 2 Versionen. Die 19200 und die 9600 Rate… je nach dem mit welcher der Drucker vorkonfiguriert wurde.

Ansteuerung

Um Daten an den Drucker zu übertragen, wird eine 5V TTL Verbindung aufgebaut. Bitte nicht verwechseln, mit der RS232 Schnittstelle eines PCs, die mit 10V arbeitet, damit würde man den Drucker zerstören.

Die Verwendung mit dem Arduino ist sehr einfach möglich, da Adafruit eine entsprechende Bibliothek entwickelt hat, die die Kommunikation mit dem Drucker sehr erleichtert. Die Bibliothek stellt folgende Funktionen bereit:

  • Inverted text: this is invoked by calling inverseOn() — you will get text that’s white-on-black instead of black-on-white. inverseOff() turns this off.
  • Double height: this makes text thats extra tall, call doubleHeightOn() — likewise, turn off with doubleHeightOff()
  • Left/Center/Right justified: this aligns text to the left or right edge of the page, or centered. You can set the alignment by calling justify(‚R‘) (for right-justified), justify(‚C‘) (for centered) or justify(‚L‘) (for left-justified). Left-justified is the default state.
  • Bold text: makes it stand out a bit more, enable with boldOn() and turn off with boldOff()
  • Underlined text: makes it stand out a bit more, enable with underlineOn() and turn off with underlineOff()
  • Large/Medium/Small text: by default we use small, medium is twice as tall, large is twice as wide/tall. Set the size with setSize(‚L‘)setSize(‚M‘) or setSize(‚S‘)
  • Line spacing: you can change the space between lines of text by calling setLineHeight() where numpix is the number of pixels. The minimum is 24 (no extra space between lines), the default spacing is 32, and double-spaced text would be 64.

Der erste Test erfolgte mit der Library von Adafruit und funktionierte nach einigem Drucken einwandfrei. Das Beispiel-Programm basiert auf dem das mit der Bibliothek mit geliefert wird. Ich habe es etwas modifiziert, da bei mir keine Bitmaps ausgedruckt werden sollen, sondern im wesentlichen Texte.

//==============================
// PH TestThermo Printer
//==============================
#include "Adafruit_Thermal.h"
#include "SoftwareSerial.h"

#define TX_PIN 6 // Arduino transmit  YELLOW WIRE  labeled RX on printer
#define RX_PIN 5 // Arduino receive   GREEN WIRE   labeled TX on printer

SoftwareSerial mySerial(RX_PIN, TX_PIN); // Declare SoftwareSerial obj first
Adafruit_Thermal printer(&mySerial);     // Pass addr to printer constructor

void setup() {
  mySerial.begin(9600);  // Initialize SoftwareSerial
  printer.begin();       // Init printer 

  // Test inverse on & off
  printer.inverseOn();   printer.println(F("Inverse ON"));
  printer.inverseOff();

  // Test character double-height on & off
  printer.doubleHeightOn(); printer.println(F("Double Height ON"));
  printer.doubleHeightOff();

  // Set text justification (right, center, left) 
  //-- accepts 'L', 'C', 'R'
  printer.justify('R');
  printer.println(F("Right justified"));
  printer.justify('C');
  printer.println(F("Center justified"));
  printer.justify('L');
  printer.println(F("Left justified"));

  // Test more styles
  printer.boldOn();
  printer.println(F("Bold text"));
  printer.boldOff();

  printer.underlineOn();
  printer.println(F("Underlined text"));
  printer.underlineOff();

  printer.setSize('L');   // Set type size, accepts 'S', 'M', 'L'
  printer.println(F("Large"));
  printer.setSize('M');
  printer.println(F("Medium"));
  printer.setSize('S');
  printer.println(F("Small"));

  printer.justify('C');
  printer.println(F("normal\nline\nspacing"));
  printer.setLineHeight(50);
  printer.println(F("Taller\nline\nspacing"));
  printer.setLineHeight(); // Reset to default
  printer.justify('L');

  printer.sleep();      // Tell printer to sleep
  delay(3000L);         // Sleep for 3 seconds
  printer.wake();       // MUST wake() before printing again, even if reset
  printer.setDefault(); // Restore printer to defaults
}

void loop() {}